Batch

Es handelt sich hierbei um eine Lösung für das Brennen mittels NeroCMD in einer Batchfile!
Es wird ein vordefiniertes Verzeichnis mit definierbaren Parametern auf CD gebrannt.

Diese Lösung funkioniert NICHT mit DVDs!

Features:

- Alle Paramter werden über Varaiblen festgelegt
- Einfache Einrichtung
- Batchfile ist ausdokumentiert

Batchfile und NeroCMD.exe sind mit angehängt!
ACHTUNG: Ahead Nero muß auf dem Rechner installiert sein!

@echo off

REM Variablen-Erklärung

REM name = Name der CD, die erstellt wird. Hier wird das Datum genommen
REM sv = Name des zu sicherden Verzeichnisses
REM nv = Nero-Verzeichnis, in dem die nerocmd.exe liegt
REM drive = Laufwerksbuchstabe des Brenners
REM Speed = Brenngeschwindigkeit

set name=%date%
set sv="C:\Dokumente und Einstellungen\[BENUTZERNAME]\Desktop\RE_Trash*.*"
set nv="C:\Programme\Ahead\Nero\nerocmd.exe"
set drive=e
set speed=32

echo Datensicherung
echo.
echo.
echo Der Brennvorgang Ihrer Daten wird gestartet
echo Es wird folgendes Verzeichnis gesichert
echo %sv%
echo.
echo Bitte legen Sie einen leeren CD-Rohling ein...

pause

%nv% --write --drivename %drive% --speed %speed% --iso %name% --create_iso_fs --verify %sv% --recursive

echo Es wurde die Sicherung %name% mit %speed%-facher Geschwindigeit auf dem Laufwerk %drive% erstellt
echo Bitte Überprüfen Sie, ob die Daten auf dem erstellten Datenträger sind.
echo vielen Dank!

[BENUTZERNAME] muss durch ihren Benutzernamen ersetzt werden

Download : NeroCmd.exe

Das Batchfile zeigt das letzte LOG-File von NT Backup an. Damit läßt sich leicht der letzte Stand der Sicherung abfragen!

@echo off
setlocal ENABLEDELAYEDEXPANSION
set file=N
set user=%UserProfile%
if {%1} NEQ {} set user=%1
set user=%user:"=%
set folder=%user%\Lokale Einstellungen\Anwendungsdaten\Microsoft\Windows NT\NTBackup\data
for /f "Tokens=*" %%a in ('dir "%folder%\backup*.log" /b /O-D') do if "!file!" EQU "N" set file=%%a
start "!file!" "%SystemRoot%\notepad.exe" "%folder%\!file!"
endlocal
exit /b 0

Hier nochmal das ganze bei dem das LOG-File in ein Verzeichnis kopiert wird:

@echo off
setlocal ENABLEDELAYEDEXPANSION
set file=N
set user=tfreitag
if {%1} NEQ {} set user=%1
set user=%user:"=%
set folder=C:\Dokumente und Einstellungen\ren-admin\Lokale Einstellungen\Anwendungsdaten\Microsoft\Windows NT\NTBackup\data
for /f "Tokens=*" %%a in ('dir "%folder%\backup*.log" /b /O-D') do if "!file!" EQU "N" set file=%%a
rem start "!file!" "%SystemRoot%\notepad.exe" "%folder%\!file!"
copy "%folder%\!file!" C:\Freigaben\Technik\Sicherung%date%.txt
endlocal
exit /b 0

Beschreibung:

Das nachfolgende Skript stellt eine perfekte Sicherung mit NTBackup da.
Das BKS-File muß mit NTBackup erstellt werden!
Die Namen der Sicherung und des Datenträerppols zum Auswurf des Bandes müssen angepaßt werden!
Alle Daten, die angepaßt werden müssen/können sind kursiv und fettgekennzeichnet
Nach der Sicherung wird eine Auftrags-Mail mit dem Logfile versendet.

ACHTUNG:

Damit das Skript läuft wird das Tool mail-as-batch.exe benötigt. Dieses ist unter der folgender Adresse herunterladbar:
Link : http://www.sql-und-xml.de/freeware-tools/ oder direkt : mail-as-batch.zip

@echo off

REM --- neue Inventur
start /wait rsm refresh /LF"Hewlett Packard DAT72 drive"

REM --- schauen, was da ist
start /wait rsm view /tphysical_media

REM --- Datensicherung starten
start /wait C:\WINDOWS\system32\ntbackup.exe backup "@C:\Dokumente und Einstellungen\ren-admin\Lokale Einstellungen\Anwendungsdaten\Microsoft\Windows NT\NTBackup\data\Voll_BAMSDC010.bks" /n "%date% Vollsicherung BAMSDC010" /d "%date% Vollsicherung BAMSDC010" /v:yes /r:no /rs:no /hc:on /m normal /j "Voll_BAMSDC010" /l:s /p "4mm DDS" /UM

REM --- Band auswerfen
REM Auswurf des Bandes, Medianame muss genau dem Name des Bandes entsprechen
rsm eject /LF"Hewlett Packard DAT72 drive"

REM --- Sicherungslog als Mail versenden
setlocal ENABLEDELAYEDEXPANSION
set file=N
set user=tfreitag
if {%1} NEQ {} set user=%1
set user=%user:"=%
set folder=C:\Dokumente und Einstellungen\ren-admin\Lokale Einstellungen\Anwendungsdaten\Microsoft\Windows NT\NTBackup\data
for /f "Tokens=*" %%a in ('dir "%folder%\backup*.log" /b /O-D') do if "!file!" EQU "N" set file=%%a
rem start "!file!" "%SystemRoot%\notepad.exe" "%folder%\!file!"
c:\mail-as-batch.exe -smtp 192.168.100.80 -from Backup@mr-daten.de -to rbamberg@mr-daten.de -s Sicherung BAMSDC010 -body "%folder%\!file!"
endlocal
exit /b 0